Distribution

This page assumes that at least one person has ZDN up and running on their computer successfully, and now you want to add additional users at your institution.

The manual way (1-2 users)

This process is fine for a few users. When there are updates to ZDN, you will just repeat this process.

• Ensure the ZDN Support Files folder is on a shared drive (See the Installation Guide for details).
• Configure the ZDN program (Settings) to connect to the shared drive
• Give each user a fresh copy of the ZDN program (program only, not the Support Files folder)

If you have more than a few users or make regular updates, you will want to automate the distribution process. This has several benefits, including being able to add additional steps to the script such as making backups along the way

The best way to distribute to multiple users is via a Windows batch file.

A batch file is a script that does multiple things. Below is the text of a batch file with notes about what each section does. This batch file is included in your original ZDN download (v2.1 and later). You do not need to copy from here. It is included here to highlight the three spots where you need to edit the code to match your local install.

Instructions:

1. Inside your ZDN folder (v2.1 and later), there is a hidden folder called "Advanced" containing a .zip file. Unzip this file
2. Right-click on the ZDN.bat file (do not open it), and select "Edit"
3. Compare the code below to the code in the file. Find the three bolded sections below and change those to your local paths.
4. Save and close your file.
5. Right-click on the Zoo Diet NaviGator shortcut (do not open it), and select "Properties"
6. Change the "Target" to wherever you just saved the .bat file.
7. Change the "Start in" to the same location, just without the filename at the end.
8. Both values should be in quotes. Neither should end with a \.
9. Double-click the shortcut to make sure everything is working correctly. If so:
   1. NaviGator should open
   2. A new folder should appear on your hard drive at C:\Data
   3. Inside C:\Data there will be a hidden folder called "Nutrition_Database"
   4. Inside that folder should be two items: A folder called "BackendBackups", which is where your backups will live. Every time ANYONE opens NaviGator using the shortcut, a backup copy of the data will be copied to their local C: drive. You must decide whether this is acceptable data security for you or not. It is helpful for backups, but obviously there will be many copies of your data floating around (hidden, but there). If you do not want this behavior, remove those lines of the code below.
   5. There will also be a local (C: drive) copy of the NaviGator front end that will always be the most recent version. So, every time you (the admin!) update NaviGator in its original location, everyone will get those changes the next time they run the script as a new copy will get downloaded each time.
10. Copy the shortcut to somewhere public and easily find-able by your users(shared drive, SharePoint, etc.).
11. Tell everyone where to find the NaviGator shortcut. They should run the shortcut from that location or copy the shortcut to their local drive/desktop. They should never open the .accdb file directly - only the shortcut. It's best if they don't even know where the original file lives. Occasionally, users will move the shortcut instead of copy it and you'll have to replace it with a new copy. That's why you COPIED the shortcut in step 10 instead of moved it ;)

< Backups and Emergencies

> Uses

The batch file

• Don't worry if you don't understand the code below. You can follow along by reading the comments.
• In batch files, any line with REM in front is treated as a comment (i.e. not run).
• You can modify this for your institution's needs and policies by removing (or adding) sections below.

---

REM This clears the screen and goes to an error if MS Access is not installed on the computer.

cls

@echo off

cls

IF NOT EXIST "C:\Program Files\Microsoft Office\root\Office16\MSACCESS.EXE" GOTO :NoAccess

REM This is a cute welcoming graphic

echo         +-+-+-+-+-+-+-+ +-+-+               

echo          W e l c o m e   t o                 

echo   +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+

echo    Z o o   D i e t   N a v i g a t o r

echo   +-+-+-+ +-+-+-+-+ +-+-+-+-+-+-+-+-+-+

echo.

echo              .-._   _ _ _ _ _ _ _ _

echo   .-''-.__.-'00  '-' ' ' ' ' ' ' ' '-.

echo   '.___ '    .   .--_'-' '-' '-' _'-' '._

echo    V: V 'vv-'   '_   '.       .'  _..' '.'.

echo      '=.____.=_.--'   :_.__.__:_   '.   : :

echo              (((____.-'        '-.  /   : :

echo                               (((-'\ .' /

echo                              _____..'  .'

echo                             '-._____.-'

REM This creates a timestamp that is used later on when naming backup files

echo Putting on my PPE...

for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"

set "YYYY=%dt:~0,4%"

set "MM=%dt:~4,2%"

set "DD=%dt:~6,2%"

set "HH=%dt:~8,2%"

set "Min=%dt:~10,2%"

set "Sec=%dt:~12,2%"

set "fullstamp=%YYYY%-%MM%-%DD%_%HH%-%Min%-%Sec%"

REM This logs each time a user opens ZDN. This can be useful if you are trying to understand who is using the software and why.

echo Hauling hay...

ECHO OPEN %fullstamp% - %USERNAME%>>"J:\ZDN\ZDN Support Files\Logs\zdn_userlog.log"

REM This creates the nested folders on the local hard drive if they don’t already exist

echo Chopping carrots...

mkdir "C:\Data\Nutrition_Database\BackendBackups" 2>NUL

attrib +h "C:\Data\Nutrition_Database" /s /d  >nul &REM This hides the folder

del "C:\Data\Nutrition_Database\*.accde"  >nul

REM This copies the frontend to the local folder. 

echo Fileting fish...

xcopy /s "J:\ZDN\ZDN_v*.accde" C:\Data\Nutrition_Database\ZDN.accde* /H /c /q /y >Nul

if ERRORLEVEL 1 goto :ERROR

cd "C:\Data\Nutrition_Database" >nul

REM This makes a backup copy of your datafile to the local folder .  You can't use it from here (unless you set a path to a complete ZDN Support Files folder). You will have to copy it to the main 'ZDN Support Files' folder to use it.

echo Bundling browse...

copy "J:\ZDN\ZDN Support Files\Datafiles\MyZooDatafile.accdb"   "C:\Data\Nutrition_Database\BackendBackups\Backup-be.accdb"  /y >nul 2>&1

cd /d "C:\Data\Nutrition_Database\BackendBackups\"

ren Backup-be.accdb %fullstamp%-ZDN-databackup.accdb REM This keeps the most recent 21 files

REM This keeps the most recent 21 files (i.e. deletes files older than the most recent 21 files)

echo Slicing strawberries...

for /F "skip=21 eol=: delims=" %%i in ('dir /b /o-d') do del %%i"

REM These lines navigate to the folder and open the database.  To the user, it just looks like they opened the database.

echo Ready to feed some animals!

start C:\Data\Nutrition_Database\ZDN.accde

TIMEOUT /T 10

goto :EOF

REM This handles errors if there's an error copying your files

:ERROR

ECHO "Oops - Can't find NaviGator files."

pause

REM This handles errors if there is no copy of Access installed

:NoAccess

ECHO Oops - No copy of MS Access detected!

ECHO.

ECHO Please tell your IT team that computer '%COMPUTERNAME:~-4%' needs Microsoft Access.

ECHO.

ECHO.

pause

:EOF